root / ImageMagick / trunk / m4 / ltdl.m4

Revision 11782, 26.1 kB (checked in by cristy, 2 weeks ago)
Line 
1# ltdl.m4 - Configure ltdl for the target system. -*-Autoconf-*-
2#
3#   Copyright (C) 1999-2006, 2007, 2008 Free Software Foundation, Inc.
4#   Written by Thomas Tanner, 1999
5#
6# This file is free software; the Free Software Foundation gives
7# unlimited permission to copy and/or distribute it, with or without
8# modifications, as long as this notice is preserved.
9
10# serial 16 LTDL_INIT
11
12# LT_CONFIG_LTDL_DIR(DIRECTORY, [LTDL-MODE])
13# ------------------------------------------
14# DIRECTORY contains the libltdl sources.  It is okay to call this
15# function multiple times, as long as the same DIRECTORY is always given.
16AC_DEFUN([LT_CONFIG_LTDL_DIR],
17[AC_BEFORE([$0], [LTDL_INIT])
18_$0($*)
19])# LT_CONFIG_LTDL_DIR
20
21# We break this out into a separate macro, so that we can call it safely
22# internally without being caught accidentally by the sed scan in libtoolize.
23m4_defun([_LT_CONFIG_LTDL_DIR],
24[dnl remove trailing slashes
25m4_pushdef([_ARG_DIR], m4_bpatsubst([$1], [/*$]))
26m4_case(_LTDL_DIR,
27        [], [dnl only set lt_ltdl_dir if _ARG_DIR is not simply `.'
28             m4_if(_ARG_DIR, [.],
29                     [],
30                 [m4_define([_LTDL_DIR], _ARG_DIR)
31                  _LT_SHELL_INIT([lt_ltdl_dir=']_ARG_DIR['])])],
32    [m4_if(_ARG_DIR, _LTDL_DIR,
33            [],
34        [m4_fatal([multiple libltdl directories: `]_LTDL_DIR[', `]_ARG_DIR['])])])
35m4_popdef([_ARG_DIR])
36])# _LT_CONFIG_LTDL_DIR
37
38# Initialise:
39m4_define([_LTDL_DIR], [])
40
41
42# _LT_BUILD_PREFIX
43# ----------------
44# If Autoconf is new enough, expand to `${top_build_prefix}', otherwise
45# to `${top_builddir}/'.
46m4_define([_LT_BUILD_PREFIX],
47[m4_ifdef([AC_AUTOCONF_VERSION],
48   [m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.62]),
49          [-1], [m4_ifdef([_AC_HAVE_TOP_BUILD_PREFIX],
50                          [${top_build_prefix}],
51                          [${top_builddir}/])],
52          [${top_build_prefix}])],
53   [${top_builddir}/])[]dnl
54])
55
56
57# LTDL_CONVENIENCE
58# ----------------
59# sets LIBLTDL to the link flags for the libltdl convenience library and
60# LTDLINCL to the include flags for the libltdl header and adds
61# --enable-ltdl-convenience to the configure arguments.  Note that
62# AC_CONFIG_SUBDIRS is not called here.  LIBLTDL will be prefixed with
63# '${top_build_prefix}' if available, otherwise with '${top_builddir}/',
64# and LTDLINCL will be prefixed with '${top_srcdir}/' (note the single
65# quotes!).  If your package is not flat and you're not using automake,
66# define top_build_prefix, top_builddir, and top_srcdir appropriately
67# in your Makefiles.
68AC_DEFUN([LTDL_CONVENIENCE],
69[AC_BEFORE([$0], [LTDL_INIT])dnl
70dnl Although the argument is deprecated and no longer documented,
71dnl LTDL_CONVENIENCE used to take a DIRECTORY orgument, if we have one
72dnl here make sure it is the same as any other declaration of libltdl's
73dnl location!  This also ensures lt_ltdl_dir is set when configure.ac is
74dnl not yet using an explicit LT_CONFIG_LTDL_DIR.
75m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl
76_$0()
77])# LTDL_CONVENIENCE
78
79# AC_LIBLTDL_CONVENIENCE accepted a directory argument in older libtools,
80# now we have LT_CONFIG_LTDL_DIR:
81AU_DEFUN([AC_LIBLTDL_CONVENIENCE],
82[_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])])
83_LTDL_CONVENIENCE])
84
85dnl aclocal-1.4 backwards compatibility:
86dnl AC_DEFUN([AC_LIBLTDL_CONVENIENCE], [])
87
88
89# _LTDL_CONVENIENCE
90# -----------------
91# Code shared by LTDL_CONVENIENCE and LTDL_INIT([convenience]).
92m4_defun([_LTDL_CONVENIENCE],
93[case $enable_ltdl_convenience in
94  no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;;
95  "") enable_ltdl_convenience=yes
96      ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;;
97esac
98LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdlc.la"
99LTDLDEPS=$LIBLTDL
100LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}"
101
102AC_SUBST([LIBLTDL])
103AC_SUBST([LTDLDEPS])
104AC_SUBST([LTDLINCL])
105
106# For backwards non-gettext consistent compatibility...
107INCLTDL="$LTDLINCL"
108AC_SUBST([INCLTDL])
109])# _LTDL_CONVENIENCE
110
111
112# LTDL_INSTALLABLE
113# ----------------
114# sets LIBLTDL to the link flags for the libltdl installable library
115# and LTDLINCL to the include flags for the libltdl header and adds
116# --enable-ltdl-install to the configure arguments.  Note that
117# AC_CONFIG_SUBDIRS is not called from here.  If an installed libltdl
118# is not found, LIBLTDL will be prefixed with '${top_build_prefix}' if
119# available, otherwise with '${top_builddir}/', and LTDLINCL will be
120# prefixed with '${top_srcdir}/' (note the single quotes!).  If your
121# package is not flat and you're not using automake, define top_build_prefix,
122# top_builddir, and top_srcdir appropriately in your Makefiles.
123# In the future, this macro may have to be called after LT_INIT.
124AC_DEFUN([LTDL_INSTALLABLE],
125[AC_BEFORE([$0], [LTDL_INIT])dnl
126dnl Although the argument is deprecated and no longer documented,
127dnl LTDL_INSTALLABLE used to take a DIRECTORY orgument, if we have one
128dnl here make sure it is the same as any other declaration of libltdl's
129dnl location!  This also ensures lt_ltdl_dir is set when configure.ac is
130dnl not yet using an explicit LT_CONFIG_LTDL_DIR.
131m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl
132_$0()
133])# LTDL_INSTALLABLE
134
135# AC_LIBLTDL_INSTALLABLE accepted a directory argument in older libtools,
136# now we have LT_CONFIG_LTDL_DIR:
137AU_DEFUN([AC_LIBLTDL_INSTALLABLE],
138[_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])])
139_LTDL_INSTALLABLE])
140
141dnl aclocal-1.4 backwards compatibility:
142dnl AC_DEFUN([AC_LIBLTDL_INSTALLABLE], [])
143
144
145# _LTDL_INSTALLABLE
146# -----------------
147# Code shared by LTDL_INSTALLABLE and LTDL_INIT([installable]).
148m4_defun([_LTDL_INSTALLABLE],
149[if test -f $prefix/lib/libltdl.la; then
150  lt_save_LDFLAGS="$LDFLAGS"
151  LDFLAGS="-L$prefix/lib $LDFLAGS"
152  AC_CHECK_LIB([ltdl], [lt_dlinit], [lt_lib_ltdl=yes])
153  LDFLAGS="$lt_save_LDFLAGS"
154  if test x"${lt_lib_ltdl-no}" = xyes; then
155    if test x"$enable_ltdl_install" != xyes; then
156      # Don't overwrite $prefix/lib/libltdl.la without --enable-ltdl-install
157      AC_MSG_WARN([not overwriting libltdl at $prefix, force with `--enable-ltdl-install'])
158      enable_ltdl_install=no
159    fi
160  elif test x"$enable_ltdl_install" = xno; then
161    AC_MSG_WARN([libltdl not installed, but installation disabled])
162  fi
163fi
164
165# If configure.ac declared an installable ltdl, and the user didn't override
166# with --disable-ltdl-install, we will install the shipped libltdl.
167case $enable_ltdl_install in
168  no) ac_configure_args="$ac_configure_args --enable-ltdl-install=no"
169      LIBLTDL="-lltdl"
170      LTDLDEPS=
171      LTDLINCL=
172      ;;
173  *)  enable_ltdl_install=yes
174      ac_configure_args="$ac_configure_args --enable-ltdl-install"
175      LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdl.la"
176      LTDLDEPS=$LIBLTDL
177      LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}"
178      ;;
179esac
180
181AC_SUBST([LIBLTDL])
182AC_SUBST([LTDLDEPS])
183AC_SUBST([LTDLINCL])
184
185# For backwards non-gettext consistent compatibility...
186INCLTDL="$LTDLINCL"
187AC_SUBST([INCLTDL])
188])# LTDL_INSTALLABLE
189
190
191# _LTDL_MODE_DISPATCH
192# -------------------
193m4_define([_LTDL_MODE_DISPATCH],
194[dnl If _LTDL_DIR is `.', then we are configuring libltdl itself:
195m4_if(_LTDL_DIR, [],
196        [],
197    dnl if _LTDL_MODE was not set already, the default value is `subproject':
198    [m4_case(m4_default(_LTDL_MODE, [subproject]),
199          [subproject], [AC_CONFIG_SUBDIRS(_LTDL_DIR)
200                          _LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"])],
201          [nonrecursive], [_LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"; lt_libobj_prefix="$lt_ltdl_dir/"])],
202          [recursive], [],
203        [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])])dnl
204dnl Be careful not to expand twice:
205m4_define([$0], [])
206])# _LTDL_MODE_DISPATCH
207
208
209# _LT_LIBOBJ(MODULE_NAME)
210# -----------------------
211# Like AC_LIBOBJ, except that MODULE_NAME goes into _LT_LIBOBJS instead
212# of into LIBOBJS.
213AC_DEFUN([_LT_LIBOBJ], [
214  m4_pattern_allow([^_LT_LIBOBJS$])
215  _LT_LIBOBJS="$_LT_LIBOBJS $1.$ac_objext"
216])# _LT_LIBOBJS
217
218
219# LTDL_INIT([OPTIONS])
220# --------------------
221# Clients of libltdl can use this macro to allow the installer to
222# choose between a shipped copy of the ltdl sources or a preinstalled
223# version of the library.  If the shipped ltdl sources are not in a
224# subdirectory named libltdl, the directory name must be given by
225# LT_CONFIG_LTDL_DIR.
226AC_DEFUN([LTDL_INIT],
227[dnl Parse OPTIONS
228_LT_SET_OPTIONS([$0], [$1])
229
230dnl We need to keep our own list of libobjs separate from our parent project,
231dnl and the easiest way to do that is redefine the AC_LIBOBJs macro while
232dnl we look for our own LIBOBJs.
233m4_pushdef([AC_LIBOBJ], m4_defn([_LT_LIBOBJ]))
234m4_pushdef([AC_LIBSOURCES])
235
236dnl If not otherwise defined, default to the 1.5.x compatible subproject mode:
237m4_if(_LTDL_MODE, [],
238        [m4_define([_LTDL_MODE], m4_default([$2], [subproject]))
239        m4_if([-1], [m4_bregexp(_LTDL_MODE, [\(subproject\|\(non\)?recursive\)])],
240                [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])])
241
242AC_ARG_WITH([included_ltdl],
243    [AS_HELP_STRING([--with-included-ltdl],
244                    [use the GNU ltdl sources included here])])
245
246if test "x$with_included_ltdl" != xyes; then
247  # We are not being forced to use the included libltdl sources, so
248  # decide whether there is a useful installed version we can use.
249  AC_CHECK_HEADER([ltdl.h],
250      [AC_CHECK_DECL([lt_dlinterface_register],
251           [AC_CHECK_LIB([ltdl], [lt_dladvise_preload],
252               [with_included_ltdl=no],
253               [with_included_ltdl=yes])],
254           [with_included_ltdl=yes],
255           [AC_INCLUDES_DEFAULT
256            #include <ltdl.h>])],
257      [with_included_ltdl=yes],
258      [AC_INCLUDES_DEFAULT]
259  )
260fi
261
262dnl If neither LT_CONFIG_LTDL_DIR, LTDL_CONVENIENCE nor LTDL_INSTALLABLE
263dnl was called yet, then for old times' sake, we assume libltdl is in an
264dnl eponymous directory:
265AC_PROVIDE_IFELSE([LT_CONFIG_LTDL_DIR], [], [_LT_CONFIG_LTDL_DIR([libltdl])])
266
267AC_ARG_WITH([ltdl_include],
268    [AS_HELP_STRING([--with-ltdl-include=DIR],
269                    [use the ltdl headers installed in DIR])])
270
271if test -n "$with_ltdl_include"; then
272  if test -f "$with_ltdl_include/ltdl.h"; then :
273  else
274    AC_MSG_ERROR([invalid ltdl include directory: `$with_ltdl_include'])
275  fi
276else
277  with_ltdl_include=no
278fi
279
280AC_ARG_WITH([ltdl_lib],
281    [AS_HELP_STRING([--with-ltdl-lib=DIR],
282                    [use the libltdl.la installed in DIR])])
283
284if test -n "$with_ltdl_lib"; then
285  if test -f "$with_ltdl_lib/libltdl.la"; then :
286  else
287    AC_MSG_ERROR([invalid ltdl library directory: `$with_ltdl_lib'])
288  fi
289else
290  with_ltdl_lib=no
291fi
292
293case ,$with_included_ltdl,$with_ltdl_include,$with_ltdl_lib, in
294  ,yes,no,no,)
295        m4_case(m4_default(_LTDL_TYPE, [convenience]),
296            [convenience], [_LTDL_CONVENIENCE],
297            [installable], [_LTDL_INSTALLABLE],
298          [m4_fatal([unknown libltdl build type: ]_LTDL_TYPE)])
299        ;;
300  ,no,no,no,)
301        # If the included ltdl is not to be used, then use the
302        # preinstalled libltdl we found.
303        AC_DEFINE([HAVE_LTDL], [1],
304          [Define this if a modern libltdl is already installed])
305        LIBLTDL=-lltdl
306        LTDLDEPS=
307        LTDLINCL=
308        ;;
309  ,no*,no,*)
310        AC_MSG_ERROR([`--with-ltdl-include' and `--with-ltdl-lib' options must be used together])
311        ;;
312  *)    with_included_ltdl=no
313        LIBLTDL="-L$with_ltdl_lib -lltdl"
314        LTDLDEPS=
315        LTDLINCL="-I$with_ltdl_include"
316        ;;
317esac
318INCLTDL="$LTDLINCL"
319
320# Report our decision...
321AC_MSG_CHECKING([where to find libltdl headers])
322AC_MSG_RESULT([$LTDLINCL])
323AC_MSG_CHECKING([where to find libltdl library])
324AC_MSG_RESULT([$LIBLTDL])
325
326_LTDL_SETUP
327
328dnl restore autoconf definition.
329m4_popdef([AC_LIBOBJ])
330m4_popdef([AC_LIBSOURCES])
331
332AC_CONFIG_COMMANDS_PRE([
333    _ltdl_libobjs=
334    _ltdl_ltlibobjs=
335    if test -n "$_LT_LIBOBJS"; then
336      # Remove the extension.
337      _lt_sed_drop_objext='s/\.o$//;s/\.obj$//'
338      for i in `for i in $_LT_LIBOBJS; do echo "$i"; done | sed "$_lt_sed_drop_objext" | sort -u`; do
339        _ltdl_libobjs="$_ltdl_libobjs $lt_libobj_prefix$i.$ac_objext"
340        _ltdl_ltlibobjs="$_ltdl_ltlibobjs $lt_libobj_prefix$i.lo"
341      done
342    fi
343    AC_SUBST([ltdl_LIBOBJS], [$_ltdl_libobjs])
344    AC_SUBST([ltdl_LTLIBOBJS], [$_ltdl_ltlibobjs])
345])
346
347# Only expand once:
348m4_define([LTDL_INIT])
349])# LTDL_INIT
350
351# Old names:
352AU_DEFUN([AC_LIB_LTDL], [LTDL_INIT($@)])
353AU_DEFUN([AC_WITH_LTDL], [LTDL_INIT($@)])
354AU_DEFUN([LT_WITH_LTDL], [LTDL_INIT($@)])
355dnl aclocal-1.4 backwards compatibility:
356dnl AC_DEFUN([AC_LIB_LTDL], [])
357dnl AC_DEFUN([AC_WITH_LTDL], [])
358dnl AC_DEFUN([LT_WITH_LTDL], [])
359
360
361# _LTDL_SETUP
362# -----------
363# Perform all the checks necessary for compilation of the ltdl objects
364#  -- including compiler checks and header checks.  This is a public
365# interface  mainly for the benefit of libltdl's own configure.ac, most
366# other users should call LTDL_INIT instead.
367AC_DEFUN([_LTDL_SETUP],
368[AC_REQUIRE([AC_PROG_CC])dnl
369AC_REQUIRE([LT_SYS_MODULE_EXT])dnl
370AC_REQUIRE([LT_SYS_MODULE_PATH])dnl
371AC_REQUIRE([LT_SYS_DLSEARCH_PATH])dnl
372AC_REQUIRE([LT_LIB_DLLOAD])dnl
373AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl
374AC_REQUIRE([LT_FUNC_DLSYM_USCORE])dnl
375AC_REQUIRE([LT_SYS_DLOPEN_DEPLIBS])dnl
376AC_REQUIRE([gl_FUNC_ARGZ])dnl
377
378m4_require([_LT_CHECK_OBJDIR])dnl
379m4_require([_LT_HEADER_DLFCN])dnl
380m4_require([_LT_CHECK_DLPREOPEN])dnl
381m4_require([_LT_DECL_SED])dnl
382
383# lt_cv_dlopen_self gets defined by LT_SYS_DLOPEN_SELF, called by LT_INIT
384if test "$lt_cv_dlopen_self" = yes; then
385  AC_DEFINE([LTDL_DLOPEN_SELF_WORKS], [1],
386    [Define if dlopen(NULL) is able to resolve symbols from the main program.])
387fi
388
389dnl Don't require this, or it will be expanded earlier than the code
390dnl that sets the variables it relies on:
391_LT_ENABLE_INSTALL
392
393dnl _LTDL_MODE specific code must be called at least once:
394_LTDL_MODE_DISPATCH
395
396# In order that ltdl.c can compile, find out the first AC_CONFIG_HEADERS
397# the user used.  This is so that ltdl.h can pick up the parent projects
398# config.h file, The first file in AC_CONFIG_HEADERS must contain the
399# definitions required by ltdl.c.
400# FIXME: Remove use of undocumented AC_LIST_HEADERS (2.59 compatibility).
401AC_CONFIG_COMMANDS_PRE([dnl
402m4_pattern_allow([^LT_CONFIG_H$])dnl
403m4_ifset([AH_HEADER],
404    [LT_CONFIG_H=AH_HEADER],
405    [m4_ifset([AC_LIST_HEADERS],
406            [LT_CONFIG_H=`echo "AC_LIST_HEADERS" | $SED 's,^[[      ]]*,,;s,[[ :]].*$,,'`],
407        [])])])
408AC_SUBST([LT_CONFIG_H])
409
410AC_CHECK_HEADERS([unistd.h dl.h sys/dl.h dld.h mach-o/dyld.h dirent.h],
411        [], [], [AC_INCLUDES_DEFAULT])
412
413AC_CHECK_FUNCS([closedir opendir readdir], [], [AC_LIBOBJ([lt__dirent])])
414AC_CHECK_FUNCS([strlcat strlcpy], [], [AC_LIBOBJ([lt__strl])])
415
416name=ltdl
417LTDLOPEN=`eval "\\$ECHO \"$libname_spec\""`
418AC_SUBST([LTDLOPEN])
419])# _LTDL_SETUP
420
421
422# _LT_ENABLE_INSTALL
423# ------------------
424m4_define([_LT_ENABLE_INSTALL],
425[AC_ARG_ENABLE([ltdl-install],
426    [AS_HELP_STRING([--enable-ltdl-install], [install libltdl])])
427
428case ,${enable_ltdl_install},${enable_ltdl_convenience} in
429  *yes*) ;;
430  *) enable_ltdl_convenience=yes ;;
431esac
432
433m4_ifdef([AM_CONDITIONAL],
434[AM_CONDITIONAL(INSTALL_LTDL, test x"${enable_ltdl_install-no}" != xno)
435 AM_CONDITIONAL(CONVENIENCE_LTDL, test x"${enable_ltdl_convenience-no}" != xno)])
436])# _LT_ENABLE_INSTALL
437
438
439# LT_SYS_DLOPEN_DEPLIBS
440# ---------------------
441AC_DEFUN([LT_SYS_DLOPEN_DEPLIBS],
442[AC_REQUIRE([AC_CANONICAL_HOST])dnl
443AC_CACHE_CHECK([whether deplibs are loaded by dlopen],
444  [lt_cv_sys_dlopen_deplibs],
445  [# PORTME does your system automatically load deplibs for dlopen?
446  # or its logical equivalent (e.g. shl_load for HP-UX < 11)
447  # For now, we just catch OSes we know something about -- in the
448  # future, we'll try test this programmatically.
449  lt_cv_sys_dlopen_deplibs=unknown
450  case $host_os in
451  aix3*|aix4.1.*|aix4.2.*)
452    # Unknown whether this is true for these versions of AIX, but
453    # we want this `case' here to explicitly catch those versions.
454    lt_cv_sys_dlopen_deplibs=unknown
455    ;;
456  aix[[4-9]]*)
457    lt_cv_sys_dlopen_deplibs=yes
458    ;;
459  amigaos*)
460    case $host_cpu in
461    powerpc)
462      lt_cv_sys_dlopen_deplibs=no
463      ;;
464    esac
465    ;;
466  darwin*)
467    # Assuming the user has installed a libdl from somewhere, this is true
468    # If you are looking for one http://www.opendarwin.org/projects/dlcompat
469    lt_cv_sys_dlopen_deplibs=yes
470    ;;
471  freebsd* | dragonfly*)
472    lt_cv_sys_dlopen_deplibs=yes
473    ;;
474  gnu* | linux* | k*bsd*-gnu)
475    # GNU and its variants, using gnu ld.so (Glibc)
476    lt_cv_sys_dlopen_deplibs=yes
477    ;;
478  hpux10*|hpux11*)
479    lt_cv_sys_dlopen_deplibs=yes
480    ;;
481  interix*)
482    lt_cv_sys_dlopen_deplibs=yes
483    ;;
484  irix[[12345]]*|irix6.[[01]]*)
485    # Catch all versions of IRIX before 6.2, and indicate that we don't
486    # know how it worked for any of those versions.
487    lt_cv_sys_dlopen_deplibs=unknown
488    ;;
489  irix*)
490    # The case above catches anything before 6.2, and it's known that
491    # at 6.2 and later dlopen does load deplibs.
492    lt_cv_sys_dlopen_deplibs=yes
493    ;;
494  netbsd*)
495    lt_cv_sys_dlopen_deplibs=yes
496    ;;
497  openbsd*)
498    lt_cv_sys_dlopen_deplibs=yes
499    ;;
500  osf[[1234]]*)
501    # dlopen did load deplibs (at least at 4.x), but until the 5.x series,
502    # it did *not* use an RPATH in a shared library to find objects the
503    # library depends on, so we explicitly say `no'.
504    lt_cv_sys_dlopen_deplibs=no
505    ;;
506  osf5.0|osf5.0a|osf5.1)
507    # dlopen *does* load deplibs and with the right loader patch applied
508    # it even uses RPATH in a shared library to search for shared objects
509    # that the library depends on, but there's no easy way to know if that
510    # patch is installed.  Since this is the case, all we can really
511    # say is unknown -- it depends on the patch being installed.  If
512    # it is, this changes to `yes'.  Without it, it would be `no'.
513    lt_cv_sys_dlopen_deplibs=unknown
514    ;;
515  osf*)
516    # the two cases above should catch all versions of osf <= 5.1.  Read
517    # the comments above for what we know about them.
518    # At > 5.1, deplibs are loaded *and* any RPATH in a shared library
519    # is used to find them so we can finally say `yes'.
520    lt_cv_sys_dlopen_deplibs=yes
521    ;;
522  qnx*)
523    lt_cv_sys_dlopen_deplibs=yes
524    ;;
525  solaris*)
526    lt_cv_sys_dlopen_deplibs=yes
527    ;;
528  sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
529    libltdl_cv_sys_dlopen_deplibs=yes
530    ;;
531  esac
532  ])
533if test "$lt_cv_sys_dlopen_deplibs" != yes; then
534 AC_DEFINE([LTDL_DLOPEN_DEPLIBS], [1],
535    [Define if the OS needs help to load dependent libraries for dlopen().])
536fi
537])# LT_SYS_DLOPEN_DEPLIBS
538
539# Old name:
540AU_ALIAS([AC_LTDL_SYS_DLOPEN_DEPLIBS], [LT_SYS_DLOPEN_DEPLIBS])
541dnl aclocal-1.4 backwards compatibility:
542dnl AC_DEFUN([AC_LTDL_SYS_DLOPEN_DEPLIBS], [])
543
544
545# LT_SYS_MODULE_EXT
546# -----------------
547AC_DEFUN([LT_SYS_MODULE_EXT],
548[m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
549AC_CACHE_CHECK([which extension is used for runtime loadable modules],
550  [libltdl_cv_shlibext],
551[
552module=yes
553eval libltdl_cv_shlibext=$shrext_cmds
554  ])
555if test -n "$libltdl_cv_shlibext"; then
556  m4_pattern_allow([LT_MODULE_EXT])dnl
557  AC_DEFINE_UNQUOTED([LT_MODULE_EXT], ["$libltdl_cv_shlibext"],
558    [Define to the extension used for runtime loadable modules, say, ".so".])
559fi
560])# LT_SYS_MODULE_EXT
561
562# Old name:
563AU_ALIAS([AC_LTDL_SHLIBEXT], [LT_SYS_MODULE_EXT])
564dnl aclocal-1.4 backwards compatibility:
565dnl AC_DEFUN([AC_LTDL_SHLIBEXT], [])
566
567
568# LT_SYS_MODULE_PATH
569# ------------------
570AC_DEFUN([LT_SYS_MODULE_PATH],
571[m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
572AC_CACHE_CHECK([which variable specifies run-time module search path],
573  [lt_cv_module_path_var], [lt_cv_module_path_var="$shlibpath_var"])
574if test -n "$lt_cv_module_path_var"; then
575  m4_pattern_allow([LT_MODULE_PATH_VAR])dnl
576  AC_DEFINE_UNQUOTED([LT_MODULE_PATH_VAR], ["$lt_cv_module_path_var"],
577    [Define to the name of the environment variable that determines the run-time module search path.])
578fi
579])# LT_SYS_MODULE_PATH
580
581# Old name:
582AU_ALIAS([AC_LTDL_SHLIBPATH], [LT_SYS_MODULE_PATH])
583dnl aclocal-1.4 backwards compatibility:
584dnl AC_DEFUN([AC_LTDL_SHLIBPATH], [])
585
586
587# LT_SYS_DLSEARCH_PATH
588# --------------------
589AC_DEFUN([LT_SYS_DLSEARCH_PATH],
590[m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
591AC_CACHE_CHECK([for the default library search path],
592  [lt_cv_sys_dlsearch_path],
593  [lt_cv_sys_dlsearch_path="$sys_lib_dlsearch_path_spec"])
594if test -n "$lt_cv_sys_dlsearch_path"; then
595  sys_dlsearch_path=
596  for dir in $lt_cv_sys_dlsearch_path; do
597    if test -z "$sys_dlsearch_path"; then
598      sys_dlsearch_path="$dir"
599    else
600      sys_dlsearch_path="$sys_dlsearch_path$PATH_SEPARATOR$dir"
601    fi
602  done
603  m4_pattern_allow([LT_DLSEARCH_PATH])dnl
604  AC_DEFINE_UNQUOTED([LT_DLSEARCH_PATH], ["$sys_dlsearch_path"],
605    [Define to the system default library search path.])
606fi
607])# LT_SYS_DLSEARCH_PATH
608
609# Old name:
610AU_ALIAS([AC_LTDL_SYSSEARCHPATH], [LT_SYS_DLSEARCH_PATH])
611dnl aclocal-1.4 backwards compatibility:
612dnl AC_DEFUN([AC_LTDL_SYSSEARCHPATH], [])
613
614
615# _LT_CHECK_DLPREOPEN
616# -------------------
617m4_defun([_LT_CHECK_DLPREOPEN],
618[m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl
619AC_CACHE_CHECK([whether libtool supports -dlopen/-dlpreopen],
620  [libltdl_cv_preloaded_symbols],
621  [if test -n "$lt_cv_sys_global_symbol_pipe"; then
622    libltdl_cv_preloaded_symbols=yes
623  else
624    libltdl_cv_preloaded_symbols=no
625  fi
626  ])
627if test x"$libltdl_cv_preloaded_symbols" = xyes; then
628  AC_DEFINE([HAVE_PRELOADED_SYMBOLS], [1],
629    [Define if libtool can extract symbol lists from object files.])
630fi
631])# _LT_CHECK_DLPREOPEN
632
633
634# LT_LIB_DLLOAD
635# -------------
636AC_DEFUN([LT_LIB_DLLOAD],
637[m4_pattern_allow([^LT_DLLOADERS$])
638LT_DLLOADERS=
639AC_SUBST([LT_DLLOADERS])
640
641AC_LANG_PUSH([C])
642
643LIBADD_DLOPEN=
644AC_SEARCH_LIBS([dlopen], [dl],
645        [AC_DEFINE([HAVE_LIBDL], [1],
646                   [Define if you have the libdl library or equivalent.])
647        if test "$ac_cv_search_dlopen" != "none required" ; then
648          LIBADD_DLOPEN="-ldl"
649        fi
650        libltdl_cv_lib_dl_dlopen="yes"
651        LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"],
652    [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if HAVE_DLFCN_H
653#  include <dlfcn.h>
654#endif
655    ]], [[dlopen(0, 0);]])],
656            [AC_DEFINE([HAVE_LIBDL], [1],
657                       [Define if you have the libdl library or equivalent.])
658            libltdl_cv_func_dlopen="yes"
659            LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"],
660        [AC_CHECK_LIB([svld], [dlopen],
661                [AC_DEFINE([HAVE_LIBDL], [1],
662                         [Define if you have the libdl library or equivalent.])
663                LIBADD_DLOPEN="-lsvld" libltdl_cv_func_dlopen="yes"
664                LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"])])])
665if test x"$libltdl_cv_func_dlopen" = xyes || test x"$libltdl_cv_lib_dl_dlopen" = xyes
666then
667  lt_save_LIBS="$LIBS"
668  LIBS="$LIBS $LIBADD_DLOPEN"
669  AC_CHECK_FUNCS([dlerror])
670  LIBS="$lt_save_LIBS"
671fi
672AC_SUBST([LIBADD_DLOPEN])
673
674LIBADD_SHL_LOAD=
675AC_CHECK_FUNC([shl_load],
676        [AC_DEFINE([HAVE_SHL_LOAD], [1],
677                   [Define if you have the shl_load function.])
678        LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la"],
679    [AC_CHECK_LIB([dld], [shl_load],
680            [AC_DEFINE([HAVE_SHL_LOAD], [1],
681                       [Define if you have the shl_load function.])
682            LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la"
683            LIBADD_SHL_LOAD="-ldld"])])
684AC_SUBST([LIBADD_SHL_LOAD])
685
686case $host_os in
687darwin[[1567]].*)
688# We only want this for pre-Mac OS X 10.4.
689  AC_CHECK_FUNC([_dyld_func_lookup],
690        [AC_DEFINE([HAVE_DYLD], [1],
691                   [Define if you have the _dyld_func_lookup function.])
692        LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dyld.la"])
693  ;;
694beos*)
695  LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}load_add_on.la"
696  ;;
697cygwin* | mingw* | os2* | pw32*)
698  AC_CHECK_DECLS([cygwin_conv_path], [], [], [[#include <sys/cygwin.h>]])
699  LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}loadlibrary.la"
700  ;;
701esac
702
703AC_CHECK_LIB([dld], [dld_link],
704        [AC_DEFINE([HAVE_DLD], [1],
705                   [Define if you have the GNU dld library.])
706                LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dld_link.la"])
707AC_SUBST([LIBADD_DLD_LINK])
708
709m4_pattern_allow([^LT_DLPREOPEN$])
710LT_DLPREOPEN=
711if test -n "$LT_DLLOADERS"
712then
713  for lt_loader in $LT_DLLOADERS; do
714    LT_DLPREOPEN="$LT_DLPREOPEN-dlpreopen $lt_loader "
715  done
716  AC_DEFINE([HAVE_LIBDLLOADER], [1],
717            [Define if libdlloader will be built on this platform])
718fi
719AC_SUBST([LT_DLPREOPEN])
720
721dnl This isn't used anymore, but set it for backwards compatibility
722LIBADD_DL="$LIBADD_DLOPEN $LIBADD_SHL_LOAD"
723AC_SUBST([LIBADD_DL])
724
725AC_LANG_POP
726])# LT_LIB_DLLOAD
727
728# Old name:
729AU_ALIAS([AC_LTDL_DLLIB], [LT_LIB_DLLOAD])
730dnl aclocal-1.4 backwards compatibility:
731dnl AC_DEFUN([AC_LTDL_DLLIB], [])
732
733
734# LT_SYS_SYMBOL_USCORE
735# --------------------
736# does the compiler prefix global symbols with an underscore?
737AC_DEFUN([LT_SYS_SYMBOL_USCORE],
738[m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl
739AC_CACHE_CHECK([for _ prefix in compiled symbols],
740  [lt_cv_sys_symbol_underscore],
741  [lt_cv_sys_symbol_underscore=no
742  cat > conftest.$ac_ext <<_LT_EOF
743void nm_test_func(){}
744int main(){nm_test_func;return 0;}
745_LT_EOF
746  if AC_TRY_EVAL(ac_compile); then
747    # Now try to grab the symbols.
748    ac_nlist=conftest.nm
749    if AC_TRY_EVAL(NM conftest.$ac_objext \| $lt_cv_sys_global_symbol_pipe \> $ac_nlist) && test -s "$ac_nlist"; then
750      # See whether the symbols have a leading underscore.
751      if grep '^. _nm_test_func' "$ac_nlist" >/dev/null; then
752        lt_cv_sys_symbol_underscore=yes
753      else
754        if grep '^. nm_test_func ' "$ac_nlist" >/dev/null; then
755          :
756        else
757          echo "configure: cannot find nm_test_func in $ac_nlist" >&AS_MESSAGE_LOG_FD
758        fi
759      fi
760    else
761      echo "configure: cannot run $lt_cv_sys_global_symbol_pipe" >&AS_MESSAGE_LOG_FD
762    fi
763  else
764    echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
765    cat conftest.c >&AS_MESSAGE_LOG_FD
766  fi
767  rm -rf conftest*
768  ])
769  sys_symbol_underscore=$lt_cv_sys_symbol_underscore
770  AC_SUBST([sys_symbol_underscore])
771])# LT_SYS_SYMBOL_USCORE
772
773# Old name:
774AU_ALIAS([AC_LTDL_SYMBOL_USCORE], [LT_SYS_SYMBOL_USCORE])
775dnl aclocal-1.4 backwards compatibility:
776dnl AC_DEFUN([AC_LTDL_SYMBOL_USCORE], [])
777
778
779# LT_FUNC_DLSYM_USCORE
780# --------------------
781AC_DEFUN([LT_FUNC_DLSYM_USCORE],
782[AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl
783if test x"$lt_cv_sys_symbol_underscore" = xyes; then
784  if test x"$libltdl_cv_func_dlopen" = xyes ||
785     test x"$libltdl_cv_lib_dl_dlopen" = xyes ; then
786        AC_CACHE_CHECK([whether we have to add an underscore for dlsym],
787          [libltdl_cv_need_uscore],
788          [libltdl_cv_need_uscore=unknown
789          save_LIBS="$LIBS"
790          LIBS="$LIBS $LIBADD_DLOPEN"
791          _LT_TRY_DLOPEN_SELF(
792            [libltdl_cv_need_uscore=no], [libltdl_cv_need_uscore=yes],
793            [],                          [libltdl_cv_need_uscore=cross])
794          LIBS="$save_LIBS"
795        ])
796  fi
797fi
798
799if test x"$libltdl_cv_need_uscore" = xyes; then
800  AC_DEFINE([NEED_USCORE], [1],
801    [Define if dlsym() requires a leading underscore in symbol names.])
802fi
803])# LT_FUNC_DLSYM_USCORE
804
805# Old name:
806AU_ALIAS([AC_LTDL_DLSYM_USCORE], [LT_FUNC_DLSYM_USCORE])
807dnl aclocal-1.4 backwards compatibility:
808dnl AC_DEFUN([AC_LTDL_DLSYM_USCORE], [])
Note: See TracBrowser for help on using the browser.